Lizenzkonfiguration automatisch über Batchdatei - LicenseToolCmd

Problem

Lösung

Obwohl die Gruppenrichtlinie von Microsoft Group Policy die beste Methode zur Bereitstellung von SELECTserver-Lizenzeinstellungen für Clientrechner ist, kann das mit Bentley-Produkten verteiltes Befehlszeilen-Lizenzierungsprogramm LicenseToolCmd, auch zur Automatisierung der Lizenzkonfiguration verwendet werden. Die folgende Batchdatei stellt eine Vorlage bereit, die eine Kopie des LicenseToolCmd verwendet, die in MicroStation V8i enthalten ist.

Wichtig:
Die Batchdatei muss vor der Verwendung geändert werden, da sie Platzhalter-Informationen für die Lizenzeinstellungen enthält. Führen Sie die folgenden Schritte aus, um sie zu ändern:

1. Speichern Sie die untere Datei und ändern Sie die Endung von TXT zu BAT.
   
   Fullscreen 8015.SetLicenseWithCmd.txt Download

   @echo off
   
   rem see http://blogs.msdn.com/david.wang/archive/2006/03/26/HOWTO-Detect-Process-Bitness.aspx 
   set _OS_X64=
   
   rem Specify the location of a log file to keep a record of the result. Specify a shared location to collect the results from multiple machines in a single file.
   set _LogFile=%temp%\BentleyComplianceLog.csv
   
   if "%PROCESSOR_ARCHITECTURE%"=="AMD64" (SET _OS_X64=1) 
   if "%PROCESSOR_ARCHITEW6432%"=="AMD64" (SET _OS_X64=1)
   
   if not defined _OS_X64 (goto 32bit)
   
   :64bit
   set _LicenseToolLocation=%ProgramFiles(x86)%\Bentley\MicroStation V8i (SELECTseries)\MicroStation
   goto ToolCheck
   
   :32bit
   set _LicenseToolLocation=%ProgramFiles%\Bentley\MicroStation V8i (SELECTseries)\MicroStation
   
   :ToolCheck
   if not exist "%_LicenseToolLocation%\LicenseToolCmd.exe" (
   	echo %UserName%,%ComputerName%,%date%,%time%,failed>> "%_LogFile%"
   	echo ERROR: License settings could not be updated.
   	echo LicenseToolCmd.exe cannot be found.
   	echo Aborting...
   	pause
   	exit /B 1
   )
   
   rem Specify SELECTserver license settings below.
   set _ServerName=selectserver.bentley.com
   set _SiteKey=AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
   
   rem Specify proxy settings below if applicable.
   rem The _ProxyServer variable can be set by itself if authentication is not required.
   rem Otherwise all three variables must be defined.
   set _ProxyServer=
   set _ProxyUser=
   set _ProxyPassword=
   
   "%_LicenseToolLocation%\LicenseToolCmd.exe" configure -setting:SELECTServer -value:%_ServerName% >NUL 2>NUL
   "%_LicenseToolLocation%\LicenseToolCmd.exe" configure -setting:ActivationKey -value:%_SiteKey% >NUL 2>NUL
   
   if not defined _ProxyServer goto DisableProxy
   "%_LicenseToolLocation%\LicenseToolCmd.exe" configure -setting:UseProxy -value:Yes >NUL 2>NUL
   "%_LicenseToolLocation%\LicenseToolCmd.exe" configure -setting:ProxyServer -value:%_ProxyServer% >NUL 2>NUL
   
   if not defined _ProxyUser goto DisableProxyAuth
   "%_LicenseToolLocation%\LicenseToolCmd.exe" configure -setting:ProxyNeedsAuth -value:Yes >NUL 2>NUL
   "%_LicenseToolLocation%\LicenseToolCmd.exe" configure -setting:ProxyUser -value:%_ProxyUser% >NUL 2>NUL
   "%_LicenseToolLocation%\LicenseToolCmd.exe" configure -setting:ProxyPassword -value:%_ProxyPassword% >NUL 2>NUL
   goto LogResult
   
   :DisableProxy
   "%_LicenseToolLocation%\LicenseToolCmd.exe" configure -setting:UseProxy -value:No >NUL 2>NUL
   goto LogResult
   
   :DisableProxyAuth
   "%_LicenseToolLocation%\LicenseToolCmd.exe" configure -setting:ProxyNeedsAuth -value:No >NUL 2>NUL
   
   :LogResult
   echo %UserName%,%ComputerName%,%date%,%time%,success>> "%_LogFile%"
   

2. Editieren Sie Datei mit einem Texteditor, beispielsweise Notepad.
3. Tauschen Sie in Zeile 33 die Variable für den Aktivierungsschlüssel mit Ihrem Standort-Aktivierungsschlüssel aus.
4. Falls Sie nicht den SELECTserver OnLine (Hosted), sondern einen eigenen Lizenzserver (Deployed) nutzen, ändern Sie die Variable für den Servernamen in Zeile 32 auch.
5. Falls Sie eine Kopie von LicenseToolCmd benutzen für ein anderes Produkt als MicroStation, müssen auch die Zeilen 15 und 19 geändert werden.
6. Für Datensatzzwecke schreibt die Batchdatei das Ergebnis auch in eine Protokolldatei. Standardmäßig wird dieses Protokoll in einem temporären Verzeichnis auf dem lokalen Rechner gespeichert. Für maximale Nützlichkeit sollten Sie einen gemeinsam genutzten Speicherort für die Variable _LogFile in Zeile 7 angeben. Auf diese Weise erhalten Sie für jeden Clientrechner, der diese Batchdatei ausführt, ein Protokoll.

Bitten Sie die Nutzer, die Batchdatei als normalen Nutzer auszuführen. Ein schwarzes Fenster erscheint für ein paar Momente. Wenn ein Fehler auftritt, bleibt das Fenster geöffnet und zeigt eine Nachricht an, bis es manuell geschlossen wird. Andernfalls schließt es automatisch.

Wird ein Clientrechner von mehreren Nutzern verwendet, führen Sie die Batchdatei stattdessen als Administrator aus, um die Lizenzeinstellungen für alle Benutzer, die auf den Computer zugreifen, zu konfigurieren.