Batchdatei zum manuellen Entfernen ausgecheckter Lizenzen auf dem Clientrechner

Problem

Eine auf dem Clientrechner ausgecheckte Lizenz wird im Lizenzmanager nicht ordnungsgemäß angezeigt.

Lösung

Nicht angezeigte ausgecheckte Lizenzen sind häufig durch Registry-Probleme verursacht.
Die folgende Batchdatei entfernt auf dem Clientcomputer alle ausgecheckten Lizenzen entweder nur vom aktuellen Benutzerprofil oder vom Profil aller Benutzer.

Da eine Lizenz aufgrund der manuellen Entfernung dann nicht für den Checkout verfügbar ist, sollte anschließend ein Administrator oder der Bentley-Lizenzierungssupport die Lizenz manuell über die SELECT Server-Administrationsseite einchecken.

Nehmen Sie hierzu folgende Schriffte vor:

1. Speichern Sie die angehängte Datei und ändern Sie die Endung von TXT zu BAT
   Fullscreen ClearCheckouts.txt Download

   @echo off
   
   rem Enabling delayed expansion provides the ability to evaluate variables at runtime.
   rem This enables variables to evaluate as expected in FOR loops.
   rem Otherwise their behavior is similar to const variables in C++.
   setlocal ENABLEDELAYEDEXPANSION
   
   set _HKCUKey=
   set _HKLMKey=
   
   rem see http://blogs.msdn.com/david.wang/archive/2006/03/26/HOWTO-Detect-Process-Bitness.aspx 
   SET _OS_X64=
   if "%PROCESSOR_ARCHITECTURE%"=="AMD64" (SET _OS_X64=1) 
   if "%PROCESSOR_ARCHITEW6432%"=="AMD64" (SET _OS_X64=1)
   
   reg query "HKCU\Software\Bentley\Licensing\1.1\Applications" >NUL 2>NUL
   if !errorlevel! == 0 (
   	set _HKCUKey=HKCU\Software\Bentley\Licensing\1.1\Applications
   )
   
   if defined _OS_X64 (
   	reg query "HKLM\SOFTWARE\Wow6432Node\Bentley\Licensing\1.1\Applications" >NUL 2>NUL
   	if !errorlevel! == 0 (
   		set _HKLMKey=HKLM\SOFTWARE\Wow6432Node\Bentley\Licensing\1.1\Applications
   	)
   ) else (
   	reg query "HKLM\SOFTWARE\Bentley\Licensing\1.1\Applications" >NUL 2>NUL
   	if !errorlevel! == 0 (
   		set _HKLMKey=HKLM\SOFTWARE\Bentley\Licensing\1.1\Applications
   	)
   )
   
   echo WARNING: This utility manually removes checked out licenses from the client side only.
   echo It does not check in the licenses on the server end. Use solely for troubleshooting.
   set /p _Response=Do you want to continue [Y/N]?
   
   if /i "%_Response%" NEQ "Y" (
   	exit /b
   )
   
   if defined _HKCUKey (
   	for /F "tokens=7 delims=\" %%A in ('reg query %_HKCUKey%') do (
   		reg query "%_HKCUKey%\%%A\Checkouts" >NUL 2>NUL
   		if !errorlevel! == 0 (
   			echo Removing checked out license for product ID %%A in current user profile...
   			reg delete "%_HKCUKey%\%%A\Checkouts" /f
   		)
   	)
   )
   
   if defined _HKLMKey (
   	echo Removing any checked out licenses from All Users profile...
   	reg delete %_HKLMKey% /f
   )

2. Machen Sie einen Rechtsklick auf diese Batch-Datei und wählen Sie im Kontextmenü „Als Administrator ausführen“ ("Run as administrator")
3. Geben Sie im nun angezeigten Fenster "j" oder "J" (bzw. y oder Y) ein, nachdem Sie die Warnhinweise gelesen haben
   

Wichtig:

Beachten Sie folgenden Hinweis zu Änderungen in der Registry:
Bevor Sie irgendwelche Änderungen durchführen, erstellen Sie bitte ein Backup der Registrierung und informieren Sie sich darüber, wie Sie das Backup verwenden können, falls später Probleme auftauchen. Informationen über das Erstellen eines Backups, dessen Wiederherstellung und die Bearbeitung der Registrierung, finden Sie in der Microsoft-Knowledge Base: http://support.microsoft.com/default.aspx?scid=kb;DE-US;256986 WARNUNG:Wird der Windows-Registry-Editor falsch angewandt, kann dies ernsthafte Probleme auf Ihrem PC verursachen und eine Neuinstallation erforderlich machen. Bentley Systems, Incorporated übernimmt keine Garantie dafür, dass Probleme durch die falsche Anwendung des Editors anschließend wieder behoben werden können. Sie verwenden den Registry-Editor auf eigenes Risiko.

Anderssprachige Quellen:

Englisch