@echo off

if not exist "%ProgramFiles%\Bentley\SELECTserver" (
	echo SELECTserver Gateway installation not detected!
	echo Aborting
	pause
	exit /B 1
)

set _TempFile=%temp%\%random%.txt

rem Retrieve and format server name
"%ProgramFiles%\Bentley\SELECTserver\LicenseToolCmd.exe" status | find "SELECT Server" > %_TempFile%
for /F "tokens=2 delims=:" %%A in (%_TempFile%) do (
	set _UnformattedServer=%%A
)
for /F "tokens=1" %%A in ("%_UnformattedServer%") do (
	set _ServerName=%%A
)

rem Retrieve and format site activation key
"%ProgramFiles%\Bentley\SELECTserver\LicenseToolCmd.exe" status | find "ActivationKey" > %_TempFile%
for /F "tokens=2 delims=:" %%A in (%_TempFile%) do (
	set _UnformattedKey=%%A
)
for /F "tokens=1" %%A in ("%_UnformattedKey%") do (
	set _SiteActivationKey=%%A
)

del "%_TempFile%"

set _GatewayName=%ComputerName%

"%ProgramFiles%\Bentley\SELECTserver\sscmd.exe" -c gatewaylic -a %_SiteActivationKey% -s %_GatewayName% -h %_ServerName% -f "%ProgramFiles%\Bentley\SELECTserver\LicenseConfiguration.xml"

if "%errorlevel%" == "0" (
	echo Gateway license file updated
)
pause