[V8i VBA] RevolveProfile

Question

We created a closed vertical shape element, and would like to convert it to solid by revolution with 360 degrees about Z axis. However, it is not successful in VBA. Great if you could provide an example.

What I have tried: 
 pointOnAxis = Point3dFromXYZ(0, 0, 0) 'Center point of Rotation

axis = Vector3dFromXYZ(0, 0, 1) 'About Z axis

angle = PI * 2 '360 degrees

Set oSmartSloidElement = RevolveProfile (profile, pointOnAxis, axis, angle)

Jan Šlegr · Accepted Answer

It required some reading and testing, but it seems it works :-) 
 But be aware it's a proof of concept, not nice, polished and stable code... 
 Option Explicit

Declare Function mdlKISolid_elementToBody Lib "stdkisolid.dll" (ByRef bodyPP As Long, ByVal edP As Long, ByVal modelRef As Long) As Long
Declare Function mdlKISolid_sweepBodyAxis Lib "stdkisolid.dll" (ByVal bodyP As Long, ByRef revolveAxisP As Point3d, ByRef radialAxisP As Point3d, ByVal angle As Double, ByVal shell As Double, ByVal draftAngle As Double, ByVal closeOpenProfiles As Long) As Long
Declare Function mdlKISolid_isSheetBody Lib "stdkisolid.dll" (ByVal bodyP As Long) As Long
Declare Function mdlKISolid_bodyToElementD Lib "stdkisolid.dll" (ByRef edPP As Long, ByVal bodyP As Long, ByVal wireframe As Long, ByVal nIsoParametrics As Long, ByVal templateP As Long, ByVal modelRef As Long, ByVal threeD As Long) As Long

Public Sub TestRevolveProfile()

' Get existing shape element
Dim shp As ShapeElement
Set shp = ActiveModelReference.GetElementByID(DLongFromLong(621))

' Convert shape to brep (KIBODY)
Dim bodyPP As Long
Dim edP As Long
edP = shp.MdlElementDescrP

Dim modelRef As Long
modelRef = ActiveModelReference.MdlModelRefP

Dim statusInt As Long
statusInt = mdlKISolid_elementToBody(bodyPP, edP, modelRef) ' Should be tested for 0

' Test if the result is really a sheet body (not used now)
Dim isSheetBody As Long
isSheetBody = mdlKISolid_isSheetBody(bodyPP)

' Revolve the sheet body
Dim statusSweep As Long

Dim revolveAxisP As Point3d
revolveAxisP = Point3dFromXYZ(0, 0, 1)

Dim radialAxisP As Point3d
radialAxisP = Point3dFromXYZ(0, 0, 0)

Dim angle As Double
angle = 2 * Pi

statusSweep = mdlKISolid_sweepBodyAxis(bodyPP, revolveAxisP, radialAxisP, angle, 0#, 0, 0) 'Should be tested for 0

' Convert the result brep body to MicroStation element
Dim statusBodyToElement As Long
Dim edPP As Long

statusBodyToElement = mdlKISolid_bodyToElementD(edPP, bodyPP, 1, -1, 0, modelRef, 1) 'Should be tested for 0

' Create VBA object based on element descriptor and add it to active model
Dim smartSolidEl As SmartSolidElement
Set smartSolidEl = MdlCreateElementFromElementDescrP(edPP)

ActiveModelReference.AddElement smartSolidEl

End Sub
 
 With regards, 
 Jan

Karsten Pudziow · Answer

with capsurface you can convert a smartsurface to a smartsolid 
 
Sub revolve() 
Dim osolid As SmartSolidElement 
Dim front_p(4) As Point3d 
Dim oline As LineElement 
Dim p1 As Point3d 
Dim p2 As Vector3d 
Dim angle As Double 
 
front_p(0) = Point3dFromXYZ(1, 0, 0) 
front_p(1) = Point3dFromXYZ(2, 0, 0) 
front_p(2) = Point3dFromXYZ(2, 0, 1) 
front_p(3) = Point3dFromXYZ(1, 0, 1) 
front_p(4) = Point3dFromXYZ(1, 0, 0) 
Set oline = CreateLineElement1(Nothing, front_p) 
 
p1 = Point3dFromXYZ(0, 0, 0) 
p2 = Vector3dFromXYZ(0, 0, 1) 
angle = Pi * 2 
 
Set osolid = SmartSolid.RevolveProfile(oline, p1, p2, angle, 0) 
osolid.CapSurface 
ActiveModelReference.AddElement osolid 
 
End Sub

Jon Summers · Answer

This works for me. Note that... 
 
 The profile is a complex line string, not a closed element 
 I've capped the surface of revolution to create a solid

I've published the code in this article about SmartSolid.RevolveProfile .

[V8i VBA] RevolveProfile

Top Replies

RevolveProfile Method