Place Text through VBA

RE: Place Text through VBA

Derek Schmidt — Fri, 01 May 2015 16:35:37 GMT

[quote]

dim text as string ' text string

dim rotmatrix as matrix3d ' text rotation

dim p1 as point3d ' textt origin

RotMatrix = Matrix3dFromAxisAndRotationAngle(2, 0)

Set Text = CreateTextElement1(Nothing, "text to be written, P1, RotMatrix)

ActiveModelReference.AddElement Testo

[/quote]

Thanks, blumax, this helped me out a lot, but I'd like to submit a correction and expansion to this like so:

dim text as TextElement
dim RotMatrix as Matrix3d
dim p1 as Point3d

' insert your own code to specify location of p1 based on your needs
RotMatrix = Matrix3dFromAxisAndRotationAngle(2, 0)

Set text = CreateTextElement1(Nothing, "your text, or a variable string", p1, RotMatrix)
' now you can set graphic group or any other properties you like, for example:
text.graphicGroup = 15

ActiveModelReference.AddElement text

Re: Place Text through VBA

Rob Golding — Thu, 11 Apr 2013 07:29:38 GMT

Perfect Stefan!

Only 1 small problem though, when the reset button is clicked nothing happens.

Is it ok to simply add in " CommandState.StartDefaultCommand"

or when working with classes is it best to do it another way?

Re: Place Text through VBA

stefan_bernsdorf — Wed, 10 Apr 2013 12:49:45 GMT

Got you wrong Rob.

I thought you wanted to place a line and a text.

Please find a example attached.

Re: Place Text through VBA

Jan Šlegr — Wed, 10 Apr 2013 11:36:38 GMT

Hi Rob,

few notes (not sitting at my computer, so sorry, no code):

Because only the first data point is important for you, you don't have to count points and you can start dynamics immediately when tool is started.
The first data point is the place where the text should be added to a model and as Stefan recommends, the tools should be restarted there.
I prefer (but it's just personal style) in such case to create text immediately when the tool is started (because you know the text already) at 0,0 coordinates and make it available for the rest of the code. Both in dynamic and datapoint you can use Transform3dFromPoint3d to create Transform3d and use it to shift the text to the dynamic or data point using textElm.Transform method.

Regards,

Jan

Re: Place Text through VBA

stefan_bernsdorf — Wed, 10 Apr 2013 10:52:21 GMT

Some small corrections:

Private Sub IPrimitiveCommandEvents_Dynamics(Point As Point3d, ByVal View As View, ByVal DrawMode As MsdDrawingMode)

If m_nPoints = 1 Then

m_atPoints(1) = Point

Dim otext As TextElement

Set otext = CreateTextElement1(Nothing, m_strText, Point, Matrix3dIdentity)

otext.Redraw msdDrawingModeTemporary

End If

End Sub

Private Sub IPrimitiveCommandEvents_Reset()

'Better to do a clear reinitialization

CommandState.StartPrimitive New MyClass()

m_nPoints = 0

End Sub

Re: Place Text through VBA

Rob Golding — Wed, 10 Apr 2013 10:41:47 GMT

Hi Jan,

The Steps listed above are correct apart from number 1.

Text is assigned from somewhere else in the VBA. Will be passed a string
Until datapoint is pressed, text is dynamically displayed at cursor. (this is so the user can see that the program is wanting the user to place text, plus being able to fit it in the design without accidently overlapping other elements)
If reset button is pressed, text is erased.
If datapoint is pressed, text is added into model and the tool is restarted.

Probably should have started a new thread, but since its still explaining how to place text in VBA i thought i would leave it. Plus i really didn't think it would be this involved!

Essentially all i want to do was do exactly what the Word Processor / text dialog box does, but instead of having the word processor display and input text, i assign the text through VBA or keyin.

Re: Place Text through VBA

Jan Šlegr — Wed, 10 Apr 2013 10:28:43 GMT

[quote user="Rob Golding"]If i add another "ActiveModelReference.AddElement otext" into the Dynamics section[/quote]

You never can do that. _Dynamics method is called when a cursor is moved, which means it can happen tens times every second. _DataPoint is the best place to add element into a model.

[quote user="Rob Golding"]Is there anything from below that could be changed to get the result the client wants?[/quote]

This thread has become pretty long and it's hard to find out what your client wants. Can you describe step by step how the tool should work ? Something like (just an example):

Tool is started, the user is asked to enter text into a dialog.
Until datapoint is pressed, text is dynamically displayed at cursor.
If reset button is pressed, text is erased.
If datapoint is pressed, text is added into model and the tool is restarted.

What I miss in the information available is a definition how mouse buttons should work.

With regards,

Jan

Re: Place Text through VBA

Rob Golding — Wed, 10 Apr 2013 08:23:11 GMT

Thanks Jan. I have had a look at the example and it was helpful but still couldn't give the result the client wants.

Below is the code that i have pieced together from the example and also from what the guys helped me with above. The exact code below, essentially work the same as before

If i add another "ActiveModelReference.AddElement otext" into the Dynamics section, then its achieves sort of what i'm after, where the text is placed at the cursor, however everytime the mouse is moved it will place the text... ending up with hundreds of text elements on the design.

Is there anything from below that could be changed to get the result the client wants?

I have seen a few programs (i think it was part of an MDL) that could do exactly as im after so i assume this is possible?

Implements IPrimitiveCommandEvents

Private m_strText As String
Private m_atPoints(0 To 1) As Point3d
Private m_nPoints As Integer

Public Property Let Text(s As String)
  m_strText = s
End Property

Sub IPrimitiveCommandEvents_Datapoint(Point As Point3d, ByVal oView As View)


    If m_nPoints = 0 Then
        CommandState.StartDynamics
        m_atPoints(0) = Point
        m_nPoints = 1
        ShowPrompt "Place end point"
    ElseIf m_nPoints = 1 Then
        m_atPoints(1) = Point
        Dim otext As TextElement
        Set otext = CreateTextElement1(Nothing, m_strText, Point, Matrix3dIdentity)
        ActiveModelReference.AddElement otext
        otext.Redraw msdDrawingModeNormal
        m_atPoints(0) = m_atPoints(1)
    End If

End Sub


Private Sub IPrimitiveCommandEvents_Dynamics(Point As Point3d, ByVal View As View, ByVal DrawMode As MsdDrawingMode)

    If m_nPoints = 1 Then
        m_atPoints(1) = Point
        Dim otext As TextElement
        Set otext = CreateTextElement1(Nothing, m_strText, Point, Matrix3dIdentity)
        otext.Redraw msdDrawingModeNormal
    End If
End Sub


Private Sub IPrimitiveCommandEvents_Keyin(ByVal Keyin As String)

End Sub


Private Sub IPrimitiveCommandEvents_Reset()
    CommandState.StartPrimitive Me
    m_nPoints = 0
End Sub


Private Sub IPrimitiveCommandEvents_Start()
    ShowPrompt "Select insertion point for text"
End Sub

Re: Place Text through VBA

Jan Šlegr — Mon, 08 Apr 2013 13:28:53 GMT

Hi Rob,

you can display dynamic elements when Primitive Command is active. The right place to do it is Dynamics methods in IPrimitiveCommandEvents, because this method is called everytime the cursor is moved.

You can check for example Line Element Creation Command example in MicroStation VBA help to see how to do it.

If there is no dynamic, Transient Elements can be used to display elements that don't exist in design file.

With regards,

Jan

Re: Place Text through VBA

Rob Golding — Mon, 08 Apr 2013 13:10:54 GMT

Just a bit further to this... the client has asked if its possible to show a preview of the text on the screen (i personally think its not needed but hey they pay the bills so least i can do is ask)

In the above, I know that VBA doesn't actually create the text element until the datapoint is clicked, so i'm not sure if this is possible.

They basically want to be able to see where the text is going to be placed, so much like the text already predefined at the cursor just waiting for a insertion point.

Any ideas?

Thanks again!

Re: Place Text through VBA

Rob Golding — Tue, 02 Apr 2013 13:24:34 GMT

You guys are absolute legends!

All working. Many thanks for helping out!

Re: Place Text through VBA

stefan_bernsdorf — Tue, 02 Apr 2013 13:17:47 GMT

You must have Procedures for all Procedures defined in your Interface.

(Just click them all once in our VBA IDE.)

Re: Place Text through VBA

Jon Summers — Tue, 02 Apr 2013 13:16:26 GMT

[quote user="Rob Golding"]Object module needs to implement 'Keyin' for interface 'IPrimitiveCommandEvents'[/quote]

In VB/VBA, a class that Implements an Interface must have all the subroutines of that Interface, even when they do nothing. In other words, you must write all the subroutines required by IPrimitiveCommandEvents. Fortunately, the IDE provides some assistance:

Top-left is a combobox having a list of classes and interfaces in your current project
1. Choose IPrimitiveCommandEvents
Top-right is a list of procedures for the current class or interface
1. As you select each procedure, VBA writes a skeleton for that procedure
2. Repeat and rinse for each procedure

Re: Place Text through VBA

Rob Golding — Tue, 02 Apr 2013 13:05:55 GMT

Happier :)

---------------------------

Microsoft Visual Basic

---------------------------

Compile error:

Object module needs to implement 'Keyin' for interface 'IPrimitiveCommandEvents'

has highlighted

Implements IPrimitiveCommandEvents

Re: Place Text through VBA

Jon Summers — Tue, 02 Apr 2013 13:00:22 GMT

[quote user="Rob Golding"]Sub IPrimitiveCommandEvents_Datapoint(point As Point3d, oView As View)[/quote]

The exact signature is

Sub IPrimitiveCommandEvents_Datapoint(point As Point3d, ByVal oView As View)

Is the compiler happier with that?

Re: Place Text through VBA

Rob Golding — Tue, 02 Apr 2013 12:51:10 GMT

Thanks Jon, much appreciated. I'm still a relative newbie to all this. Its a hell of a learning curve!

Its skipped over that part but now it comes up with another message.

Compile error:

Procedure declaration does not match description of event or procedure having the same name

Its highlighted the ...

Sub IPrimitiveCommandEvents_Datapoint(point As Point3d, oView As View)

Re: Place Text through VBA

Jon Summers — Tue, 02 Apr 2013 12:47:54 GMT

[quote user="stefan_bernsdorf"]Your Property needs a Getter![/quote]

A VB/VBA class property lets you assign data to an object or get data from an object. You can write either or both properties, although it's usual to write both.

A class having only a Set or Let property is write-only
A class having only a Get property is read-only
A class having both Get and Set or Let properties is read-write

Re: Place Text through VBA

Jon Summers — Tue, 02 Apr 2013 12:39:26 GMT

Syntax of Class Properties

When you write a class property with VB/VBA...

use the Set keyword when assigning an object
use the Let keyword when assigning plain old data (POD), such as a number or string
use the Get keyword to extract data from the class

In your screenshot, the incomprehensible error message is trying to tell you to use Let rather tha Set in your Text property. Try this instead:

Public Property Let Text (s As String)
m_strText = s
End Property

Apologies

[quote user="Rob Golding"]What have I done wrong?[/quote]

Nothing! That was my fault for writing the wrong keyword in my example below. I'm always forgetting to use Let for PODs.

Re: Place Text through VBA

stefan_bernsdorf — Tue, 02 Apr 2013 11:56:32 GMT

Your Property needs a Getter! Google your error text, you will find an answer.

Re: Place Text through VBA

Rob Golding — Tue, 02 Apr 2013 11:44:19 GMT

I understand the highlighted part is the error but not too sure why its appearing.

I have attached the picture rather than embed it.

Thanks for the replies guys.

Re: Place Text through VBA

stefan_bernsdorf — Tue, 02 Apr 2013 11:07:22 GMT

See the highlighted portion of your code? Thats the error. Unfortunately the Screenshot is too small, could not read it.

But I can see it is not the part you copied into your mail.

Re: Place Text through VBA

Rob Golding — Tue, 02 Apr 2013 10:45:09 GMT

Thanks Jon,

I haven't been able to get that to work unfortunatley.

I have done as above...

-Created a Class Module called "clsGolding" which has the following in it... But when run the below error appears.

My form has a button that simply is this

 PlaceTextInteractive ("testing")

Which controls this

Sub PlaceTextInteractive(s As String)
  Dim oTextPlacer As New clsGolding
  oTextPlacer.Text = s
  CommandState.StartPrimitive oTextPlacer
End Sub

What have I done wrong?

Re: Place Text through VBA

Jon Summers — Thu, 28 Mar 2013 12:26:03 GMT

[quote user="Rob Golding"]The only thing is that i would like the user to place the text where they would like, is there a way Ii can put the new text element to the cursor and have the user select the point?[/quote]

Write a class that Implements IPrimitiveCommandEvents. Read about Interface Oriented Programming in VBA help. Start that class from your form and pass it the string to be created.

Sub PlaceTextInteractive (s As String)
Dim oTextPlacer As New clsGolding
oTextPlacer.Text = s
CommandState.StartPrimitive oTextPlacer
End Sub

Create a class module named clsGolding. Put the following in that class...

Implements IPrimitiveCommandEvents

Private m_strText As String

[Edit] ' wrong: Public Property Set Text (s As String)
Public Property Let Text (s As String)

m_strText = s
End Property

' Add all the subroutines required by IPrimitiveCommandEvents

Sub IPrimitiveCommandEvents_Datapoint (point As Point3d, oView As View)
Dim oText As TextElement
Set oText = CreateTextElement1 (Nothing, m_strText, point, Matrix3dIdentity)
ActiveModelReference.AddElement oText
End Sub

Re: Place Text through VBA

Rob Golding — Thu, 28 Mar 2013 07:50:52 GMT

Thanks for the replies. Has basically got what i wanted.

The only thing is that i would like the user to place the text where they would like, is there a way i can put the new text element to the cursor and have the user select the point? rather than define the point?

Re: Place Text through VBA

Jon Summers — Mon, 25 Mar 2013 12:59:52 GMT

[quote user="Rob Golding"] CadInputQueue.SendKeyin "place text"
CadInputQueue.SendKeyin sText[/quote]

In general, if you queue a user key-in using VBA then the result is the same as if you performed that task manually. In other words, MicroStation can't distinguish between you typing place dialogtext icon and VBA queueing place dialogtext icon.

If a key-in causes MicroStation to pop a dialog, then it will pop that dialog.

If you want to avoid the consequents of a user key-in, then use VBA to create objects directly, in the way that others have suggested. Search VBA help for examples. Searching for CreateTextElement1 reveals an example under topic Elements and Levels.